// Based on Greenberg 11-16

Spring[] segments = new Spring[30];

void setup()
{
  size(400,400);
  smooth();

  // Construct segments, with size and spring parameters depending on position along worm
  for (int i=0; i<segments.length; i++) {
    int r;
    if (i > segments.length/2) r = segments.length-i;  // smaller toward either end
    else r = i;
    // These numbers are pretty magical, from Greenberg
    segments[i] = new Spring(width/2, height/2, r, .0035*(i+1), .95-.02*i);
  }
}

void draw()
{
  background(0);
  
  for (int i=0; i<segments.length; i++) segments[i].draw();
  
  // Recenter first segment
  // Rather than targeting mouse position, target a constant-sized (speed)
  // step toward the mouse position
  float speed = 25;
  float dx = mouseX-segments[0].x, dy = mouseY-segments[0].y;
  float d = sqrt(dx*dx+dy*dy);
  // dx/d and dy/d give the fractions of the diagonal step that lie in the two directions
  if (d>0) segments[0].update(segments[0].x+speed*dx/d, segments[0].y+speed*dy/d);

  // Recenter each following segment at preceding segment
  for (int i=1; i<segments.length; i++)
    segments[i].update(segments[i-1].x, segments[i-1].y);
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}