// Based on R&F synthesis "soda processing", 
// which is in turn based on the Soda Constructor, http://www.sodaplay.com

// The arrays of balls and springs
int maxBalls=1000, maxSprings=1000;
Ball[] balls = new Ball[maxBalls];
Spring[] springs = new Spring[maxSprings];
// How far we are into the arrays (how many have been created)
int currBall=0, currSpring=0;
// If a ball has been selected, its index (-1 if none)
int selBall=-1;
// Universal spring constant and drag coefficient
// (each Ball and Spring has its own field, so they could be set independently)
float k=0.1, drag=0.95; 
// Whether we are building (adding balls and springs) -- true
// or simulating -- false
boolean building=true;

void setup()
{
  size(400,400);
  smooth();
}

void draw()
{
  // Show mode by way of background
  if (building) background(128);
  else background(255);
  // Draw the springs first
  stroke(0); strokeWeight(2);
  for (int i=0; i<currSpring; i++)
    springs[i].draw();
  // Now draw the balls
  noStroke();
  for (int i=0; i<currBall; i++) {
    if (i == selBall) fill(0,255,0);  // highlight the selected one
    else fill(0);
    balls[i].draw();
  }
  
  if (!building) {
    // Simulate
    // First apply the spring forces
    for (int i=0; i<currSpring; i++)
      springs[i].apply();
    // Then update the ball velocities and positions
    for (int i=0; i<currBall; i++)
      balls[i].update();
  }
}

void mousePressed()
{
  // See if any ball is close enough to be selected
  // I found it useful to give a little slop -- 1.5*radius
  int sel = -1;
  for (int i=0; i<currBall; i++) {
    if (dist(mouseX,mouseY, balls[i].x,balls[i].y) < 1.5*balls[i].r) sel = i;
  }
  if (!building) {
    // When simulating, just remember that the ball was selected
    selBall = sel;
  }
  else if (sel < 0) { // Nobody's close
    if (selBall >= 0) { // Had previously selected -- cancel that
      selBall = -1;
    }
    else if (currBall<maxBalls-1) { // Add a new one
      balls[currBall] = new Ball(mouseX,mouseY,drag);
      currBall++;
    }
  }
  else { // Selected a ball -- must select two to add a spring
    if (selBall < 0) { // This is the first selected
      selBall = sel;
    }
    else if (selBall == sel) { // Same one twice -- cancel
      selBall = -1;
    }
    else if (currSpring<maxSprings-1) { // Second one -- make spring
      springs[currSpring] = new Spring(balls[selBall],balls[sel],k);
      currSpring++;
      selBall = -1;
    }
  }      
}

void mouseDragged()
{
  if (!building && selBall >= 0) {
    // When simulating, move ball and set its velocity
    balls[selBall].x = mouseX;
    balls[selBall].y = mouseY;
    balls[selBall].vx = mouseX-pmouseX;
    balls[selBall].vy = mouseY-pmouseY;
  }
}

void mouseReleased()
{
  if (!building) selBall = -1;
}

void keyPressed()
{
  if (key=='b') building=true;
  else if (key=='s') building=false;
  else if (key=='k') setK(k*0.5);
  else if (key=='K') setK(min(k*2,0.999));
  else if (key=='d') setDrag(1-(1-drag)*0.5);
  else if (key=='D') setDrag(max(1-(1-drag)*2,0.001));
}

// Set the spring constant for all springs
void setK(float newK)
{
  k = newK;
  println("k:"+k);
  for (int i=0; i<currSpring; i++) springs[i].k = k;
}

// Set the drag coefficient for all balls
void setDrag(float newDrag)
{
  drag = newDrag;
  println("drag:"+drag);
  for (int i=0; i<currBall; i++) balls[i].drag = drag;
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}