// Dartmouth CS 2, Winter 2009, Chris Bailey-Kellogg
// Notes 15 | Sketch 2

Ball[] balls = new Ball[10];
int dragging = -1;  // which ball is being dragged (-1 if none)

int G = 50;  // strength of repulsion

void setup()
{
  size(400,300);
  smooth();
  noStroke();

  // Start them at random places
  for (int i=0; i<balls.length; i++)
    balls[i] = new Ball(random(width),random(height)); 
}

void draw()
{
  background(0);
  
  // Draw each
  for (int i=0; i<balls.length; i++) {
    if (i == dragging) fill(255,0,0);
    else fill(255);
    balls[i].draw();
  }
  
  // Apply repulsion for each pair
  for (int i=0; i<balls.length; i++) {
    for (int j=i+1; j<balls.length; j++) {
      float dij = dist(balls[i].x,balls[i].y, balls[j].x,balls[j].y);
      if (dij > 0) {
        // Compute repulsive force, and the fraction in each direction
        float f = G/(dij*dij);
        float dx = (balls[j].x-balls[i].x)/dij;
        float dy = (balls[j].y-balls[i].y)/dij;
        // Push each away from the other (unless being dragged)
        if (i != dragging) {
          balls[i].vx -= f*dx;
          balls[i].vy -= f*dy;
        }
        if (j != dragging) {
          balls[j].vx += f*dx;
          balls[j].vy += f*dy;
        }
      }
    }
  }
  // Update velocities and positions
  for (int i=0; i<balls.length; i++) {
    if (i != dragging) balls[i].update();
  }
}

void mousePressed()
{
  // See if beginning to drag
  dragging = -1;
  for (int i=0; i<balls.length; i++)
    if (dist(mouseX,mouseY, balls[i].x,balls[i].y) < balls[i].r)
      dragging = i;
}

void mouseDragged()
{
  // If dragging, update position
  if (dragging >= 0) {
    balls[dragging].x = mouseX;
    balls[dragging].y = mouseY;
  }
}

void mouseReleased()
{
  // Stop dragging and put it at rest (0 velocity)
  if (dragging >= 0) {
    balls[dragging].vx = 0;
    balls[dragging].vy = 0;
    dragging = -1;
  }
}

void keyPressed()
{
  if (key=='G') {  // more repulsion
    G+=10;
    println("G:"+G);
  }
  else if (key=='g') {  // less repulsion
    if (G>10) {
      G-=10;
      println("G:"+G);
    }
  }
  else if (key=='s') {  // stop
    for (int i=0; i<balls.length; i++) {
      balls[i].vx=0; balls[i].vy=0;
    }
  }
  else if (key=='r') {  // reset positions and velocities
    for (int i=0; i<balls.length; i++) {
      balls[i].x = random(width); balls[i].y = random(height);
      balls[i].vx = 0; balls[i].vy = 0;
    }
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}