// Dartmouth CS 2, Winter 2009, Chris Bailey-Kellogg
// Notes 15 | Sketch 3
// Like Sketch 2, but using Traer Physics package

import traer.physics.*;

Particle[] ps = new Particle[10];
int dragging = -1;  // which particle is being dragged (-1 if none)
int r=10; // uniform radius

ParticleSystem physics;
int G = 1000;  // strength of repulsion


void setup()
{
  size(400,300);
  smooth();
  noStroke(); 
  
  // Create the physics module, with no inherent gravity and a small amount of drag
  physics = new ParticleSystem(0,0.1);
  
  // Create the particles, with uniform mass of 1, starting at random positions
  for (int i=0; i<ps.length; i++)
    ps[i] = physics.makeParticle(1,random(width),random(height),0);

  // Make them repel each other
  for (int i=0; i<ps.length; i++)
    for (int j=i+1; j<ps.length; j++)
      physics.makeAttraction(ps[i], ps[j], -G, r/2);
}

void draw()
{
  background(0);

  // Draw each
  for (int i=0; i<ps.length; i++) {
    if (i==dragging) fill(255,0,0);
    else fill(255);
    ellipse(ps[i].position().x(), ps[i].position().y(), 2*r,2*r);
  }
  
  // Update    
  physics.tick();
  for (int i=0; i<ps.length; i++)
    handleBoundaryCollisions(ps[i]);
}

// Bounce off the wall (and lose a little velocity)
// From an example at the traer.physics site
void handleBoundaryCollisions(Particle p)
{
  if (p.position().x() < 0 || p.position().x() > width)
    p.velocity().set(-0.9*p.velocity().x(), p.velocity().y(), 0);
  if (p.position().y() < 0 || p.position().y() > height)
    p.velocity().set(p.velocity().x(), -0.9*p.velocity().y(), 0);
  p.position().set(constrain(p.position().x(), 0, width), constrain(p.position().y(), 0, height), 0); 
}

void mousePressed()
{
  // See if beginning to drag
  dragging = -1;
  for (int i=0; i<ps.length; i++) {
    if (dist(mouseX,mouseY, ps[i].position().x(),ps[i].position().y()) < r)
      dragging = i;
  }
  if (dragging >= 0) ps[dragging].makeFixed();
}

void mouseDragged()
{
  // If dragging, update position
  if (dragging >= 0)
    ps[dragging].position().set(mouseX,mouseY,0);
}

void mouseReleased()
{
  // Stop dragging and put it at rest (0 velocity)
  if (dragging >= 0) {
    ps[dragging].makeFree();
    ps[dragging].velocity().set(0,0,0);
    dragging = -1;
  }
}

void keyPressed()
{
  if (key=='G') {  // more repulsion
    G+=100;
    println("G:"+G);
  }
  else if (key=='g') {  // less repulsion
    if (G>100) {
      G-=100;
      println("G:"+G);
    }
  }
  else if (key=='s') {  // stop
    for (int i=0; i<ps.length; i++)
      ps[i].velocity().set(0,0,0);
  }
  else if (key=='r') {  // reset positions and velocities
    for (int i=0; i<ps.length; i++) {
      ps[i].position().set(random(width),random(height),0);
      ps[i].velocity().set(0,0,0);
    }
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}