// Sets the vertices and edges of the graph from the info in the file,
// which should be in a simple Pajek-like format:
// *Vertices #      where # is the number of vertices
// id1 label1       where id is a number and label a string, in double quotes if it has a space
// id2 label2
// ...
// id# label#
// *Edges
// ida1 idb1        where the ids are those of the connected vertices
// ida2 idb2
// ...
void readPajek(Graph g, String filename)
{
  Vertex[] vertices = null;
  int[] ids = null; // keep track of vertex ids, for lookup (parallels vertices)
  Edge[] edges = null;
  int vn=0, en=0;   // vertex and edge numbers, so far

  String[] lines = loadStrings(filename);
  int mode=0;       // 0: before vertices; 1: vertices; 2: edges
  for (int i=0; i<lines.length; i++) {
    String l = lines[i];
    String lc = l.toLowerCase();
    String[] words = splitTokens(l, " ");
    if (lc.startsWith("*vertices")) {
      mode = 1;
      if (words.length!=2) println("invalid vertices format");
      else {
        int num = int(words[1]);
        vertices = new Vertex[num];
        ids = new int[num];
        edges = new Edge[num]; // guessing -- will expand as needed
      }
    }
    else if (lc.startsWith("*edges")) {
      mode = 2;
    }
    else if (mode==1) {
      if (words.length < 2) println("invalid vertex format:"+l);
      else if (vn == vertices.length) println("too many vertices");
      else {
        ids[vn] = int(words[0]);
        // get label as quoted substring if quotes...
        int start = l.indexOf('"')+1, end = l.lastIndexOf('"');
        if (start == 0) {  // ... or everything after space otherwise
          start = l.indexOf(' ')+1;
          end = l.length();
        }
        vertices[vn] = new Vertex(l.substring(start,end));
        vn++;
      }
    }
    else if (mode==2) {
      if (en == edges.length) edges = (Edge[])expand(edges);
      // map from ids to vertices
      int i1 = find(ids, int(words[0])), i2 = find(ids, int(words[1]));
      if (i1==-1 || i2==-1) println("invalid edge "+l);
      Vertex v1 = vertices[i1], v2 = vertices[i2];
      if (words.length!=2) println("invalid edge "+l);
      else {
        edges[en] = new Edge(v1, v2);
        en++;
      }
    }
    else println("ignoring "+l);
  }
  // wrap up
  if (vn < vertices.length) println("Too few vertices");
  g.vertices = vertices;
  g.edges = (Edge[])subset(edges,0,en);
}

// Returns the index of the key in the array; -1 if not found
// (Binary search)
int find(int[] a, int key)
{
  int l=0, r=a.length-1;
  while (l<=r) {
    int m = (l+r)/2;
    if (a[m] == key) return m;
    else if (a[m] < key) l = m+1;
    else r = m-1;
  }
  return -l;
}