// Based on Reas & Fry Synthesis 1

PImage[] imgs = new PImage[15]; // An array of images

void setup()
{
  size(800,600);
  smooth();
  background(0);
  imageMode(CENTER);
  frameRate(20); // slow it down
  
  // The images are named "rome-1.jpg", "rome-2.jpg", etc.
  for (int i=0; i<imgs.length; i++)
    imgs[i] = loadImage("rome-"+(i+1)+".jpg");
}

void draw()
{
  // fade away olf stuff
  fill(0,1); rectMode(CORNER); rect(0,0,width,height);
  
  // once in while add an image
  if(frameCount % 20 == 0) {
    // pick a random image from the array
    PImage img = imgs[int(random(imgs.length))];
    
    // random position and rotation
    //translate(random(img.width,width-img.width),
    //          random(img.height,height-img.height));
    //rotate(random(-PI/4,PI/4));
    translate(random(100,width-100),random(100,height-100));
    rotate(random(radians(-15),radians(15)));
  
    // paint the image and a border
    fill(255); rectMode(CENTER); rect(0,0,img.width+20,img.height+20);
    image(img,0,0,img.width,img.height);
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}