PImage[] imgs = new PImage[4]; // loaded images
PImage img;                    // current image
int curImg = 0;                // current image

Wanderer[] particles;

void setup()
{
  size(300,450);
  smooth();
  
  for(int i = 0; i < imgs.length; i ++) imgs[i] = loadImage("img-"+(i+1)+"-tiny.jpg");
  img = imgs[curImg];
  
  // start it up
  startParticles();
}

void startParticles() {
  // get the ratio size between the image and the screen
  float r = (0.5*width)/img.width;
  
  // Create a particle for each pixel
  particles = new Wanderer[img.height*img.width];
  int i = 0;  // which ball to add next
  for (int y=0; y<img.height; y++) {
    for (int x=0; x<img.width; x++) {
      particles[i] = new Wanderer(x*r*2,y*r*2,r,img.get(x,y));
      i++;
    }
  }
}

void draw()
{
  background(0);
  for (int i=0; i<particles.length; i++) particles[i].draw();
  for (int i=0; i<particles.length; i++) particles[i].update();
}

void keyPressed() {
  if(key == ' ') {
    curImg = (curImg+1)%imgs.length;
    img = imgs[curImg];
    startParticles();
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}