PImage[] imgs = new PImage[4]; // loaded images
PImage img;                    // current image
int curImg = 0;                // current image

void setup()
{
  size(400,600);
  
  for(int i = 0; i < imgs.length; i ++) imgs[i] = loadImage("img-"+(i+1)+".jpg");
  img = imgs[curImg];
}

PImage filterThreshold(PImage src) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  float threshold = map(mouseX,0,width,32,200); // threshold
  for (int i=0; i<src.pixels.length; i++) {
    float b = brightness(src.pixels[i]);
    if(b > threshold) ret.pixels[i] = color(255);
    else ret.pixels[i] = color(0);
  }
  ret.updatePixels();
  return ret;
}

// Based on Greenberg 10-34
PImage filterContrast(PImage src) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  float contrast = map(mouseX,0,width,0,.01);  // factor by which to push toward either 0 or 255
  for (int i=0; i<src.pixels.length; i++) {
    color p=src.pixels[i];
    float r=red(p), g=green(p), b=blue(p);
    r = constrain(r+r*contrast*(r-127.5), 0,255);
    g = constrain(g+g*contrast*(g-127.5), 0,255);
    b = constrain(b+b*contrast*(b-127.5), 0,255);
    ret.pixels[i] = color(r,g,b);
  }
  ret.updatePixels();
  return ret;  
}

// Based on Greenberg 10-41
PImage filterInvert(PImage src) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  float invertMag = map(mouseX,0,width,0,1);  // factor by which to invert
  for (int y=0; y<src.height; y++) {
    float invert=y*255.0/img.height;
    for (int x=0; x<src.width; x++) {
      color p=pget(src,x,y);
      float b = brightness(p);
      float nb = b*(1-invertMag)+invertMag*abs(invert-b);
      float r = nb/b;
      pset(ret,x,y,color(red(p)*r,green(p)*r,blue(p)*r));
    }
  }
  ret.updatePixels();
  return ret;  
}

void draw()
{
  // compute the filtered images
  PImage f1 = filterThreshold(img);
  PImage f2 = filterContrast(img);
  PImage f3 = filterInvert(img);
  
  // draw them
  background(0);  
  image(img,0,0);
  image(f1,0,height/2);
  image(f2,width/2,0);
  image(f3,width/2,height/2);
}

void keyPressed()
{
  if(key == ' ') {
    curImg = (curImg+1)%imgs.length;
    img = imgs[curImg];
  }
}

// START NO NOTES
// code used to capture screenshots
void pset(int x, int y, color c) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  pixels[x+width*y] = c; 
}
color pget(int x, int y) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  return pixels[x+width*y]; 
}
void pset(PImage i, int x, int y, color c) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  i.pixels[x+i.width*y] = c; 
}
color pget(PImage i, int x, int y) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  return i.pixels[x+i.width*y]; 
}

void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}