PImage[] imgs = new PImage[4]; // loaded images
PImage img;                    // current image
int curImg = 0;                // current image

void setup()
{
  size(400,600);
  
  for(int i = 0; i < imgs.length; i ++) imgs[i] = loadImage("img-"+(i+1)+".jpg");
  img = imgs[curImg];
}

PImage filterFlip(PImage src) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  for (int y=0; y<src.height; y++) {
    for (int x=0; x<src.width; x++) {
      pset(ret,x,y,pget(src,src.width-1-x,y));
    }
  }
  ret.updatePixels();
  return ret;
}

PImage filterLens(PImage src, int lx, int ly, int lr) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  for (int y=0; y<src.height; y++) {
    for (int x=0; x<src.width; x++) {
      float d = dist(x,y,lx,ly)/lr; // distance to lens center normalized
      if(d >= 1) pset(ret,x,y,pget(src,x,y)); // do nothing outside
      else pset(ret,x,y,pget(src,lx+int((x-lx)*d),ly+int((y-ly)*d)));
    }
  }
  ret.updatePixels();
  return ret;
}

PImage filterScramble(PImage src, float sx) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  for (int y=0; y<src.height; y++) {
    for (int x=0; x<src.width; x++) {
      pset(ret,x,y,pget(src,int(random(x-sx,x+sx)),int(random(y-sx,y+sx))));
    }
  }
  ret.updatePixels();
  return ret;
}

void draw() {
  // compute the filtered images
  PImage f1 = filterFlip(img);
  PImage f2 = filterScramble(img,map(mouseX,0,width,1,10));
  PImage f3 = filterLens(img,mouseX-width/2,mouseY-height/2,50);
  
  // draw them
  background(0);  
  image(img,0,0);
  image(f1,0,height/2);
  image(f2,width/2,0);
  image(f3,width/2,height/2);
}

void keyPressed()
{
  if(key == ' ') {
    curImg = (curImg+1)%imgs.length;
    img = imgs[curImg];
  }
}

// START NO NOTES
// code used to capture screenshots
void pset(int x, int y, color c) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  pixels[x+width*y] = c; 
}
color pget(int x, int y) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  return pixels[x+width*y]; 
}
void pset(PImage i, int x, int y, color c) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  i.pixels[x+i.width*y] = c; 
}
color pget(PImage i, int x, int y) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  return i.pixels[x+i.width*y]; 
}

void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}