PImage[] imgs = new PImage[4]; // loaded images
PImage img;                    // current image
int curImg = 0;                // current image

void setup() 
{
  size(400,600);
  smooth();
  rectMode(CENTER);
  
  for(int i = 0; i < imgs.length; i ++) imgs[i] = loadImage("img-"+(i+1)+".jpg");
  img = imgs[curImg];
}

PImage filterAverage(PImage src, int s) {
  PImage ret = new PImage(src.width,src.height);
  // loop over the pixel I want to write to
  for (int y=0; y<ret.height; y++) {
    for (int x=0; x<ret.width; x++) {
      // add together the values for all the neighbors
      float r=0, g=0, b=0; float w=0;
      for (int dy=-s; dy<=s; dy++) {
        for (int dx=-s; dx<=s; dx++) {
          // our routines make sure we do not go out of bounds
          color p=pget(src,x+dx,y+dy); 
          r += red(p); g += green(p); b += blue(p);
          w++;
        }
      }
      // set the color as the average
      pset(ret,x,y,color(r/w,g/w,b/w));
    }
  }
  ret.updatePixels();
  return ret;
}

PImage filterDiff(PImage src, int s) {
  PImage ret = new PImage(src.width,src.height);
  // loop over the pixel I want to write to
  for (int y=0; y<ret.height; y++) {
    for (int x=0; x<ret.width; x++) {
      // add together the values for all the neighbors
      float r=0, g=0, b=0; float w=0;
      for (int dy=-s; dy<=s; dy++) {
        for (int dx=-s; dx<=s; dx++) {
          // our routines make sure we do not go out of bounds
          color p=pget(src,x+dx,y+dy);
          float k = 0;
          if(dx ==0 && dy == 0) k = (2*s+1)*(2*s+1);
          else k = -1;
          r += k*red(p); g += k*green(p); b += k*blue(p);
          w += k;
        }
      }
      // set the color as the average
      pset(ret,x,y,color(r/w,g/w,b/w));
    }
  }
  ret.updatePixels();
  return ret;
}

PImage filterBlur(PImage src, int s) {
  PImage ret = new PImage(src.width,src.height);
  // loop over the pixel I want to write to
  for (int y=0; y<ret.height; y++) {
    for (int x=0; x<ret.width; x++) {
      // add together the values for all the neighbors
      float r=0, g=0, b=0; float w=0;
      for (int dy=-s; dy<=s; dy++) {
        for (int dx=-s; dx<=s; dx++) {
          // our routines make sure we do not go out of bounds
          color p=pget(src,x+dx,y+dy); 
          float ks = 1-constrain(dist(x,y,x+dx,y+dy)/s,0,1); // count more the central one
          r += ks*red(p); g += ks*green(p); b += ks*blue(p);
          w += ks;
        }
      }
      // set the color as the average
      pset(ret,x,y,color(r/w,g/w,b/w));
    }
  }
  ret.updatePixels();
  return ret;
}

void draw() {
  // compute the filtered images
  PImage f1 = filterAverage(img,int(map(mouseX,0,width,1,8)));
  PImage f2 = filterDiff(img,int(map(mouseX,0,width,1,8)));
  PImage f3 = filterBlur(img,int(map(mouseX,0,width,1,8)));
  
  // draw them
  background(0);  
  image(img,0,0);
  image(f1,0,height/2);
  image(f2,width/2,0);
  image(f3,width/2,height/2);
}

void keyPressed() {
  if(key == ' ') {
    curImg = (curImg+1)%imgs.length;
    img = imgs[curImg];
  }
}

// START NO NOTES
// code used to capture screenshots
void pset(int x, int y, color c) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  pixels[x+width*y] = c; 
}
color pget(int x, int y) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  return pixels[x+width*y]; 
}
void pset(PImage i, int x, int y, color c) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  i.pixels[x+i.width*y] = c; 
}
color pget(PImage i, int x, int y) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  return i.pixels[x+i.width*y]; 
}

void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}