// Uses camie file from Processing example Libraries | Video (Movie) | Loop

import processing.video.*; // video library

Capture cam;

void setup()
{
  size(640,720);
  smooth();
  rectMode(CENTER);
  
  // load and start the camie
  cam = new Capture(this, 320, 240);
  cam.start();
}

// Same as with images
PImage filterContrast(PImage src) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  float contrast = 0.01;  // factor by which to push toward either 0 or 255
  for (int i=0; i<src.pixels.length; i++) {
    color p=src.pixels[i];
    float r=red(p), g=green(p), b=blue(p);
    r = constrain(r+r*contrast*(r-127.5), 0,255);
    g = constrain(g+g*contrast*(g-127.5), 0,255);
    b = constrain(b+b*contrast*(b-127.5), 0,255);
    ret.pixels[i] = color(r,g,b);
  }
  ret.updatePixels();
  return ret;  
}

// Same as with images
PImage filterScramble(PImage src, float sx) {
  PImage ret = new PImage(src.width,src.height); // make a new image
  for (int y=0; y<src.height; y++) {
    for (int x=0; x<src.width; x++) {
      pset(ret,x,y,pget(src,int(random(x-sx,x+sx)),int(random(y-sx,y+sx))));
    }
  }
  ret.updatePixels();
  return ret;
}

void draw()
{ 
  if(cam.available()) {
    cam.read(); cam.loadPixels();
    
    // apply filters
    PImage f1 = filterContrast(cam);
    PImage f2 = filterScramble(cam,5);
    
    // draw frames
    background(0);
    image(cam,cam.width/2,0,cam.width,cam.height);
    image(f1,0,cam.height,cam.width,cam.height);
    image(f2,cam.width,cam.height,cam.width,cam.height);
    
    // draw a rect mosaic
    pushMatrix();
    translate(0,cam.height*2);
    noStroke();
    float s = 8;
    for (float y = s/2; y < cam.height; y += s+1) {
      for (float x = s/2; x < cam.width; x += s+1) {
        fill(pget(cam,int(x),int(y)));
        rect(x,y,s,s);
      }
    }
    popMatrix();
    
    // draw a rect mosaic
    pushMatrix();
    translate(cam.width,cam.height*2);
    noStroke(); fill(255);
    for (float y = s/2; y < cam.height; y += s+1) {
      for (float x = s/2; x < cam.width; x += s+1) {
        color pixel = pget(cam,int(x),int(y));
        float b = brightness(pixel) / 255.0;
        rect(x,y,s*b,s*b);
      }
    }
    popMatrix();
  }
}

// START NO NOTES
// code used to capture screenshots
void pset(int x, int y, color c) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  pixels[x+width*y] = c; 
}
color pget(int x, int y) { 
  x = constrain(x,0,width-1);
  y = constrain(y,0,height-1);
  return pixels[x+width*y]; 
}
void pset(PImage i, int x, int y, color c) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  i.pixels[x+i.width*y] = c; 
}
color pget(PImage i, int x, int y) { 
  x = constrain(x,0,i.width-1);
  y = constrain(y,0,i.height-1);
  return i.pixels[x+i.width*y]; 
}

void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}