// Simplified from Greenberg 2-01

// how many recursions drawing branches, and overall (rest drawing "leaves")
int branchDepth=4, leafDepth=6;

void setup()
{
  size(450,300);
}

void draw() {
  if(frameCount % 60 != 0) return;

  background(255);
  strokeWeight(20);
  stroke(30,10,5);
  float trunkLength = random(65,90);
  int numTrunkSegments = floor(random(7,12));
  float x = orgLine(width/2,height, width/2,height-trunkLength, numTrunkSegments, 22);
  branch(x, height-trunkLength, 0, 12, 25, 15);
}

// x and y are start of branch
// depth is how many recursive calls
// thickness is weight of stroke for branch
// xo and yo are initial offsets for incrementing x and y (plus an additional random amount)
void branch(float x, float y, int depth, float thickness, float xo, float yo)
{
  if (depth <= leafDepth) {
    int numBranches=2; // more numerous branches higher up
    if (depth>branchDepth) numBranches = floor(random(2,17));
    int dir=1; // alternate left/right
    for (int i=0; i<numBranches; i++) {
      // end of branch
      float x2 = x+dir*(xo+random(-15,15));
      float y2 = y-yo+random(-20,20);
      dir = -dir;

      // draw branch
      strokeWeight(thickness);
      // branch or "leaf" color
      if (depth <= branchDepth) stroke(30,10,5);
      else stroke(random(60),random(50,140),random(20),230);
      // line(x,y, x2,y2);
      x2 = orgLine(x,y, x2,y2, 8, 5);

      // branches shorten and thin out
      float thick2 = thickness*pow(0.75,numBranches);
      float xo2, yo2;
      if (depth<branchDepth) {
        xo2 = xo-numBranches*random(.5);
        yo2 = yo-numBranches*random(.25);
      }
      else {
        xo2 = xo-numBranches*random(1.5);
        yo2 = yo-numBranches*random(.75);
      }

      // recursive call
      branch(x2,y2,depth+1,thick2,xo2,yo2);
    }
  } 
}

// generates oragnic looking branches
// y will end up at y1, but x may be off some, so it's returned
float orgLine(float x1, float y1, float x2, float y2, int numSections, int maxTwist)
{
  float dx=(x2-x1)/numSections, dy=(y2-y1)/numSections;

  float x=x1, y=y1;
  // each section increments y by dy, and x by dx plus a random "twist" amount
  for (int i=0; i<numSections; i++) {
    float twist = random(-maxTwist,maxTwist);
    float xn=x+dx+twist, yn=y+dy;
    line(x,y, xn,yn);
    x = xn; y = yn;
  }

  return x;
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}