float[] x, y;  // Coordinates of the points on the curve
int depth;     // How deeply we've recurse

void setup()
{
  size(400,400);
  smooth();
  background(255);
  initKoch();
  drawSnowFlake();
}

void drawSnowFlake()
{
  pushMatrix();
  translate(width/4,height/4);
  drawCurve(x,y);
  popMatrix();

  pushMatrix();
  translate(width*3/4,height/4);
  rotate(radians(120));
  drawCurve(x,y);
  popMatrix();

  pushMatrix();
  translate(width/2, height/4+width/2*sin(radians(60)));
  rotate(radians(240));
  drawCurve(x,y);
  popMatrix();
}

void draw()
{}

// Each time the mouse is pressed, recurse one more level
void mousePressed()
{
  background(255);
  depth++;
  if (depth==6) initKoch(); // wrap around
  else expandKoch();
  println(depth);
  drawSnowFlake();
}

// Set up the initial curve -- a horizontal line
void initKoch()
{
  depth = 0;
  x = new float[2];
  y = new float[2];
  x[0] = 0; y[0] = 0;
  x[1] = width/2; y[1] = 0;
}

// Update the points by putting a triangular part jutting out
// between each pair of points in the current set
void expandKoch()
{
  // new points
  int l2 = 1 + 4*(x.length-1);
  float[] x2 = new float[l2], y2 = new float[l2];
  // index into new points
  int i2=0;
  
  for (int i=0; i<x.length-1; i++) {
    // consider each adjacent pair of points
    float dx = x[i+1]-x[i], dy = y[i+1]-y[i];
    // first point is the same
    x2[i2] = x[i]; y2[i2] = y[i];
    // second point is 1/3-way between
    x2[i2+1] = x[i]+dx/3; y2[i2+1] = y[i]+dy/3;
    // third point is 1/2-way between, sticking out
    x2[i2+2] = x[i]+dx/2 + sin(radians(60))*dy/3;
    y2[i2+2] = y[i]+dy/2 - sin(radians(60))*dx/3;
    // fourth point is 2/3-way between
    x2[i2+3] = x[i]+dx*2/3; y2[i2+3] = y[i]+dy*2/3;
    i2 += 4;
  }
  // last point is the same
  x2[l2-1] = x[x.length-1]; y2[l2-1] = y[y.length-1];
  x = x2; y = y2;
}

// draw a shape with vertices for the points
void drawCurve(float[] x, float[] y)
{
  beginShape();
  for (int i=0; i<x.length; i++)
    vertex(x[i],y[i]);
  endShape();
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  if(key == '`' && !online) save("sketch.png");
}