/*
  This is the fourth part of building a 4-step Sequencer Synthesizer modeling 
 the one found at:
 
 http://www.handmadeelectronicinstruments.com/store/product/four-step-sequencer-synthesizer/
 
 We know have a working 4-step Sequencer Synthesizer, but why not add some more
 visual feedback? With some minor modifications, we make the window twice as
 high and draw the audio waveform. Most of the mods are done in setup() (to
 make the window taller and replace the controls), and at the top of draw().
 We also need to make some minor changes to getZone().
 
 Andy Sarroff, 2/2014
 */

import beads.*;

int uiX;
int bSize;
color c;
PImage bgimg;
PImage ledOn;
PImage ledOff;
PImage swOn;
PImage swOff;
int zone = -1;
Control[] controls = new Control[7];
Switch[] switches = new Switch[5];
Clock cl;

// create our AudioContext, which will oversee audio input/output
AudioContext ac;
Glide[] glides = new Glide[7];
BiquadFilter lpf;
WavePlayer[] wp = new WavePlayer[4];
ScalingMixer sc;
Gain g;

void setup() {
  size(692, 692);  
  // http://img.ehowcdn.com/default/ehow/images/a07/fd/m6/types-brushed-aluminum-sheets-1.1-800x800.jpg 
  bgimg = loadImage("aluminum.jpg");
  // The following parameter will store the y-coordinate of the top of the 
  // user interface
  uiX = bgimg.height;
  bgimg.resize(bgimg.width*2, bgimg.height*2);
  // Set size of window to match background image
  imageMode(CENTER);
  // Load images
  // http://openclipart.org/image/300px/svg_to_png/88123/led_red_black.png
  ledOn = loadImage("led.png");
  ledOn.resize(ledOn.width/10, 0);
  ledOff = loadImage("ledOff.png");
  ledOff.resize(ledOff.width/10, 0);
  // http://www.yourpowercentre.com.au/wp-content/uploads/2013/10/switch.jpg
  swOn = loadImage("swOn.png");
  swOn.resize(swOn.width/3, 0);
  swOff = loadImage("swOff.png");
  swOff.resize(swOff.width/3, 0);
  // http://578e7a9bafc08e847f59-b21544d490ba797ec9de9d17e947de3d.r81.cf1.rackcdn.com/lrs-18519e_7379.jpg
  PImage img = loadImage("knob_t.png");
  img.resize(img.width/4, 0);

  background(bgimg);

  // The following code has been modified to displace the controls in the y
  // direction by the value stored in uiX.

  // Inititalize controls
  for (int i=0; i<controls.length; i++)
  {
    if (i == 0) {
      controls[i] = new Control(img, width/8, uiX+img.height/2, 0);
    } else if (i < 3) {
      controls[i] = new Control(img, width/8+(i+1)*width/4, uiX+img.height/2, 0);
    } else {
      controls[i] = new Control(img, width/8+(i-3)*width/4, height-img.height/2, 0);
    }
  }

  // Inititalize switches
  for (int i=0; i<switches.length; i++) {
    if (i == 4) {
      switches[i] = new Switch(width/8+width/4, uiX+img.height/2, swOn, swOff);
    } else {
      switches[i] = new Switch(width/8+i*width/4, uiX+height/4, ledOn, ledOff);
    }
  }
  fill(0);
  strokeWeight(3);
  colorMode(HSB);
  c = color(126, 255, 255);
  initializeAudio();
}

void initializeAudio() {
  ac = new AudioContext();
  sc = new ScalingMixer(ac);
  for (int i=0; i<controls.length; i++) {
    switch (i) {
    case 0: // Tempo
      glides[i] = new Glide(ac, 1, 50);
      cl = new Clock(ac, glides[i]);
      Trigger tr = new Trigger();
      cl.addMessageListener(tr);
      ac.out.addDependent(cl);
      controls[i].ll = 4000;
      controls[i].ul = 1;
      controls[i].ctrl = 500;
      break;
    case 1: // LPF
      glides[i] = new Glide(ac, 0, 50);
      // The BiquadFilter constructor (or doc) has a bug. The class 
      // must be instantiated with minimal input parameters and then
      // the attributes may be set individually.
      lpf = new BiquadFilter(ac, 1);
      lpf.setType(BiquadFilter.LP);
      lpf.setFrequency(glides[i]);
      lpf.setQ(2.0);
      controls[i].ll = 0;
      controls[i].ul = 1000;
      controls[i].ctrl = 300;
      break;
    case 2: // Gain
      glides[i] = new Glide(ac, 0, 50);
      g = new Gain(ac, 1, glides[i]);
      controls[i].ll = 0;
      controls[i].ul = 0.25;
      controls[i].ctrl = 0.025;
      break;
    default:
      glides[i] = new Glide(ac, 0, 50);
      wp[i-3] = new WavePlayer(ac, glides[i], Buffer.SQUARE);
      sc.addInput(wp[i-3]);
      controls[i].ll = 0;
      controls[i].ul = 3000;
      controls[i].ctrl = (i-2)*150;
      break;
    }
    controls[i].gl = glides[i];
    controls[i].setAngle();
    controls[i].update();
    controls[i].draw();
  }
  lpf.addInput(sc);
  g.addInput(lpf);
  ac.out.addInput(g);
  bSize = ac.getBufferSize();
  ac.stop();
}

void draw() {
  background(bgimg);
  stroke(0);
  // Draw a black rectangle at the top. Then grab the data sitting in the
  // output buffer of the audioContext. Make a shape with it by drawing a bunch 
  // of vertices. The data is scaled in the x an y directions so that it fits
  // the black rectangle.

  // Some notes:
  // The default frame rate is approximately 60 frames per second and the 
  // default buffer size is 512 samples. This means that we will draw 
  // approximately 60 * 512 = 30720 samples per second. Yet the default sample 
  // rate is 44100 samples a second. This means that we will not be drawing
  // all samples.
  rect(0, 0, width, uiX);
  stroke(c);
  float [] buf = ac.out.getOutBuffer(0);
  beginShape(LINES);
  for (int i=0; i<buf.length; i++) {
    vertex(width*i/bSize, (buf[i]+1)*uiX/2);
  }
  endShape();
  for (int i=0; i<controls.length; i++) {
    controls[i].draw();
  }
  for (int i=0; i<switches.length; i++) {
    switches[i].draw();
  }
  if (mousePressed) {
    updateControl();
  }
}

void getZone() {
  // split screen into 3x4 grid of zones:
  // --------------------------
  // |  0  |  1  |  2   |  3  |
  // --------------------------
  // |  4  |  5  |  6   |  7  |
  // --------------------------
  // |  8  |  9  |  10  |  11 |
  // --------------------------

  // Some changes were made to move the zoning to the bottom half of the screen
  // There is a minor bug here, which allows the zone to be set if the mouse is 
  // near the bottom of the black rectangle above the controls.
  zone = 4*mouseX/width + 3*(mouseY-uiX)/( height-uiX)*4; //<>//
  //println(zone);
}

void updateControl() {
  if (zone == 0) {
    controls[zone].update();
  } else if (zone >= 2 && zone <=3) {
    controls[zone-1].update();
  } else if (zone >=8 && zone <= 11) {
    controls[zone-5].update();
  }
}

void mousePressed() {
  getZone();
  if (zone == 1) {
    switches[4].on = !switches[4].on;
    if (switches[4].on) {
      ac.start();
    } else {
      for (int i=0; i<4; i++) {
        switches[i].on = false;
      }
      ac.stop();
    }
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  boolean online = true;
  if (key == '`' && !online) save("sketch.png");
}