/*
  This is the second part of building a 4-step Sequencer Synthesizer modeling the 
 one found at :
 
 http://www.handmadeelectronicinstruments.com/store/product/four-step-sequencer-synthesizer/
 
 In this step we add some interaction to the images. In particular, we turn 
 the knobs and switches into two classes and allow interaction via the mouse.
 
 Andy Sarroff, 2/2014
 */

PImage bgimg;
PImage ledOn;
PImage ledOff;
PImage swOn;
PImage swOff;
int zone;
Control[] controls = new Control[7];
Switch[] switches = new Switch[5];

void setup() {
  size(692, 346);
  // http://img.ehowcdn.com/default/ehow/images/a07/fd/m6/types-brushed-aluminum-sheets-1.1-800x800.jpg 
  bgimg = loadImage("aluminum.jpg");
  bgimg.resize(bgimg.width*2, bgimg.height);
  // Load images
  imageMode(CENTER);
  // http://openclipart.org/image/300px/svg_to_png/88123/led_red_black.png
  ledOn = loadImage("led.png");
  ledOn.resize(ledOn.width/10, 0);
  ledOff = loadImage("ledOff.png");
  ledOff.resize(ledOff.width/10, 0);
  // http://www.yourpowercentre.com.au/wp-content/uploads/2013/10/switch.jpg
  swOn = loadImage("swOn.png");
  swOn.resize(swOn.width/3, 0);
  swOff = loadImage("swOff.png");
  swOff.resize(swOff.width/3, 0);
  // http://578e7a9bafc08e847f59-b21544d490ba797ec9de9d17e947de3d.r81.cf1.rackcdn.com/lrs-18519e_7379.jpg
  PImage img = loadImage("knob_t.png");
  img.resize(img.width/4, 0);

  // Set size of window to match background image
  background(bgimg);

  // Initialize controls
  for (int i=0; i<controls.length; i++)
  {
    if (i == 0) {
      //leds[4] = new Led(width/8+j*width/4, y, swOn, swOff);
      controls[i] = new Control(img, width/8, img.height/2, 0);
    } else if (i < 3) {
      controls[i] = new Control(img, width/8+(i+1)*width/4, img.height/2, 0);
    } else {
      controls[i] = new Control(img, width/8+(i-3)*width/4, height-img.height/2, 0);
    }
  }

  // Inititalize switches
  for (int i=0; i<switches.length; i++) {
    if (i == 4) {
      switches[i] = new Switch(width/8+width/4, img.height/2, swOn, swOff);
    } else {
      switches[i] = new Switch(width/8+i*width/4, height/2, ledOn, ledOff);
    }
  }
}

void draw() {
  // Very simple here... draw all the controls and switches. If the mouse is 
  // pressed, call updateControl. Using the mousePressed conditional here allows
  // the user to user to turn the controls interactively, at the same rate as
  // the frame rate (which defaults to 60 fps).
  background(bgimg);
  for (int i=0; i<controls.length; i++) {
    controls[i].draw();
  }
  for (int i=0; i<switches.length; i++) {
    switches[i].draw();
  }
  if (mousePressed) {
    updateControl();
  }
}

void getZone() {
  // split screen into 3x4 grid of zones:
  // --------------------------
  // |  0  |  1  |  2   |  3  |
  // --------------------------
  // |  4  |  5  |  6   |  7  |
  // --------------------------
  // |  8  |  9  |  10  |  11 |
  // --------------------------
  // The following code computes which "zone" the mouse is in
  zone = 4*mouseX/width + 3*mouseY/height*4;
  //println(zone);
}

void updateControl() {
  // This function maps a zone to the correct control instance and calls the 
  // instance's update method.
  if (zone == 0) {
    controls[zone].update();
  } else if (zone >= 2 && zone <=3) {
    controls[zone-1].update();
  } else if (zone >=8 && zone <= 11) {
    controls[zone-5].update();
  }
}

void mousePressed() {
  // We use void mousePressed(), which gets called only once for each mouse 
  // press. This way the zone is updated only once per mouse press. We 
  // additionally use this function to flip the on/off switch
  getZone();
  if (zone == 1) {
    switches[4].on = !switches[4].on;
  }
}

// START NO NOTES
// code used to capture screenshots
void keyReleased() {
  boolean online = true;
  if (key == '`' && !online) save("sketch.png");
}